读入数据的问题

由于我之前发的帖子被沉下去了，再次发帖求助。

附件有数据，现在的问题是有部分内容的中间加入了回车符，使一条记录在2行显示，用外部读入法读入的时候就被当成2条记录读入了。
现在希望能解决这个问题，经过大家的帮助，我现在有2条思路。第一条是用input方式读入，可以解决回车的问题，有人帮写了代码如下：
data test;
   infile 'E:\样本.txt' lrecl=300 dlm='“,' dsd firstobs=2;
    input
                city :$6.
                quxian :$18.
                yingyeting : $42.
                staff_id : $10.
                staff_name : $33.
                SERIAL_NUMBER  
                RECOMM_DATE : $19.
                yewu : $18.
                qudao :$10.
                jieshou_flag :$6.
    ;
run;
这里有一个问题是，yingyeting这个变量中有逗号，这样有部分记录就会被拆散，后来我用逗号做分隔符，加入dsd选项，但第二行的引号却又被当做一个变量读入了。有点左右为难，哪位高手能在这方面给继续解决一下，不胜感激。

第二条思路是用函数compbl和compress组合将回车符拿掉，只可惜我才疏学浅，在读入阶段怎么用搞不清楚，哪位高手能用这个方法解决一下，小弟谢过了！

1# 040108020007

filename dt 'D:\temp';
data tem;
   infile dt(Sample.txt) lrecl=400 truncover;
   input line $400.;
   file dt(S2.txt);
   if _n_ ne 1 then do;
      if length(compress(line,'"','K')) < 20 then do;
      input line2 $400.;
         line = trim(line)||' '||left(line2);
         end;
   end;
   output;
   put line;
run;
proc import datafile='D:\temp\S2.txt' out=dstnm dbms=csv replace;
run;   

以上程序仅针对所提供的文本文件，若更多的行对应一个观测可相应地修改程序


P1.txt (412 Bytes)

2010-10-27 16:32:04 上传

这个程序，版权所有: 大牛pobel
http://www.pinggu.org/bbs/space.php?username=pobel
原帖地址：
http://www.pinggu.org/bbs/thread-945109-1-1.html

2# jiagangw

jiagangw 前辈的代码真是精彩！ 此致敬礼！

一直在想怎样通过一个DATA步实现，通过学习前辈代码，现在终于实现了：

data test;
   infile "c:\files\test.txt" lrecl=400 dsd dlm="," truncover firstobs=2;
   length temp $400;
   input @ ;
   temp=_infile_;
   do while (length(compress(temp,'"','K')) < 20);
      input;
   input @;
        temp= cats(temp,_infile_);
   end;
   _infile_=temp;
   keep city--jieshou_flag;
    input @1
                city :$6.
                quxian :$18.
                yingyeting : $42.
                staff_id : $10.
                staff_name : $33.
                SERIAL_NUMBER  
                RECOMM_DATE : $19.
                yewu : $18.
                qudao :$10.
                jieshou_flag :$6.
    ;
run;

这个莫非就是传说中的汪嘉冈老师？

这么厉害！