sas hash表的 汇总问题

是 否 +2 论坛币

k人 参与回答

经管之家送您一份

应届毕业生专属福利!

求职就业群

赵安豆老师微信：zhaoandou666

经管之家联合CDA

送您一个全额奖学金名额~ !

立即领取

感谢您参与论坛问题回答

经管之家送您两个论坛币！

+2 论坛币

各位大虾：
在sas/hash中碰到下面一个问题，一直苦于无法解决，请各位大虾帮忙：
例如（实际客户上万个）：A客户有三条记录，每条记录的金额均小于200,；B客户有5条记录，每条记录的金额均大于150，但小于400。
在hash中，如何实现下面条件？
条件：如果某个客户的总金额（该客户所有记录的金额加和）<600，则将该客户的所有记录删除。
如上例中，A客户总金额<600，则删除A客户。

不用sql解决，只用sas/hash解决，并且一步实现

扫码加我 拉你入群

请注明：姓名-公司-职位

以便审核进群资格，未注明则拒绝

分享0 收藏6 回帖

关键词：HASH Has 总问题 如何实现 下面条 汇总 SAS HASH

data test;
     input id $ amount;
     datalines;
A  189
B  160
B  188
B  165
A  145
A  199
B  198
B  345
;


data wanted;
    if 0 then set test;
    if _n_=1 then do;
            declare hash h();
                    h.definekey('id');
                        h.definedata('id','total');
                        h.definedone();
        end;
        do until(last);
            set test end=last;
                if h.find()=0 then do;
            total+amount;
                        h.replace();
                end;
                else do;
                     total=amount;
             h.add();
                end;
         end;
         do until(last1);
         set test end=last1;
                 if h.find()=0 and total>=600 then output;
         end;
         drop total;
         stop;
run;

非常感谢，再多问一句，如果有另一个表（test1），内有字段id、name等，想用一个data步实现关联和筛选，我写的程序如下，结果是name一栏全为空？：
data wanted;
    if 0 then set test1;
    if _n_=1 then do;
        declare hash h();
                h.definekey('id');
                h.definedata('id','name','total');
                h.definedone();
    end;
    do until(last);
        set test end=last;
        if h.find()=0 then do;
            total+amount;
            name=name;
            h.replace();
         end;
         else do;
             total=amount;
             name=name;
             h.add();
         end;
     end;
     do until(last1);
         set test end=last1;
         if h.find()=0 and total>=600 then output;
     end;
     drop total;
     stop;
run;

data test;
     input id $ amount;
     datalines;
A  189
B  160
B  188
B  165
A  145
A  199
B  198
B  345
;

data test1;
    input id $ name $;
datalines;
A Jose
B Hose'B'
;

data wanted;
    if 0 then set test test1;
    if _n_=1 then do;
            declare hash h();
                    h.definekey('id');
                        h.definedata('id','total');
                        h.definedone();

            declare hash h_name(dataset:'test1');
                    h_name.definekey('id');
                        h_name.definedata('id','name');
                        h_name.definedone();
        end;
        do until(last);
            set test end=last;
                if h.find()=0 then do;
            total+amount;
                        h.replace();
                end;
                else do;
                     total=amount;
             h.add();
                end;
         end;
         do until(last1);
               set test end=last1;
               if h.find()=0 and total>=600 then do;
                        h_name.find();
                        output;
                end;
         end;
         drop total;
         stop;
run;

谢谢！

学习了
hash我还是停留在小表连大表速度快的应用上

楼主，你好，请问hash、hiter类能否在SAS8版本中使用？我把上面的代码原封不动的搬到PGM窗口运行，错误如下：
                 180
NOTE: SCL source line.
230                      h.definekey('id');
                                    -
                                    22
ERROR: Invalid variable specification, h.definekey.
        Variable names of the form X.X must be either FIRST.X or LAST.X
NOTE: SCL source line.
231                          h.definedata('id','total');
                                         -
                                         22
                                         76
ERROR: Invalid variable specification, h.definedata.
        Variable names of the form X.X must be either FIRST.X or LAST.X
只写上面这些了，楼主帮我找下原因吧

mark下

学习了一下，谢谢各位前辈。

学习鸟~~~