一行同属性数据变为多行

sas数据表如下：

              id          citing_1            citing_2           citing_3
              1             11                     12                     13
              2             21                     22                     23


想变成如下格式：

              id              citing
              1                 11
              1                 12
              1                 13
              2                 21
              2                 22
              2                 23

请教大侠给编个程呗！

data test;
input id $  citing_1  citing_2  citing_3;
cards;
1 11 12 13
2 21 22 23
;
proc transpose data=test out=new(drop=_: rename=(col1=citing));
   by id;
   var citing_:;
run;

If the name of the variables are not in a consequential way, you can use the following syntax:
data test;
input id $  citing_1  citing2a  citing2b;
cards;
1 11 12 13
2 21 22 23
;
proc sql;
select id, citing_1 from work.test
union all
select id, citing2a from work.test
union all
select id, citing2b from work.test;

抱歉，再问一句哦！
如果citing_1中没有数据
例如： id     citing_1       citing_2       citing_3
          1                           12               13
          2         21               22               23
该怎么写命令啊？

data test;
input id $  citing_1  citing_2  citing_3;
cards;
1  . 12 13
2 21 22 23
;
proc transpose data=test out=new(drop=_: rename=(col1=citing) where=(^missing(citing)));
   by id;
   var citing_:;
run;

data a ;
input id c_1-c_3;
cards;
1 11 12 13
2 21 22 23
;
run;
data a1;
set a;
retain id;
array c_[*] c_1-c_3;
array x[*] x1-x3;
do i=1 to dim(c_);
        x[i]=c_[i];
        citing=x[i];
output;
end;
run;

data a ;
input id$ c f b;
cards;
1 11 12 13
2 21 22 23
;
run;
data a12(keep=id citing);
set a;
retain id;
array c_[*] _numeric_;
array x[*] x1-x3;
do i=1 to dim(c_);
        x[i]=c_[i];
        citing=x[i];
output;
end;
run;