发帖
雷达卡
在本书提供的资源中，Scene_11_3_3 场景演示了如何实现顶点动画阴影的计算。该示例基于 11.3.1 节中的核心代码，通过顶点位移模拟出水流波动的视觉效果。为了展示阴影，场景中启用了平行光的阴影投射功能，并添加了一个平面用于接收由“水流”产生的阴影。
首先，将 Scene_11_3_1 另存为 Scene_11_3_3，以便在新场景中进行修改和测试。
接着，在场景中创建一个 Plane 对象，作为接收水流阴影的表面。
确保 Plane 和 water_full 对象的渲染器组件中均启用了 cast shadows 与 receive shadows 选项，以支持阴影的投射与接收。
在项目中新建一个名为 Chapter11-VertexAnimationWithShadow.shader 的着色器文件。可以通过访问以下链接获取原始 Water Shader 的参考代码：
https://github.com/candycat1992/Unity_Shaders_Book/blob/master/Assets/Shaders/Chapter11/Chapter11-VertexAnimationWIthShadow.shader
将 Chapter11-Water.shader 中的主逻辑复制到新的着色器中，并额外添加一个 ShadowCaster Pass，用于正确生成动态阴影。
Shader "Custom/Chapter11-VertexAnimationWithShadow"
{
Properties {
_MainTex ("Main Tex", 2D) = "white" {} //_MainTex是河流纹理
_Color ("Color Tint", Color) = (1, 1, 1, 1)
_Magnitude ("Distortion Magnitude", Float) = 1 //_Magnitude用于控制水流波动的幅度
_Frequency ("Distortion Frequency", Float) = 1 //_Frequency用于控制波动频率
_InvWaveLength ("Distortion Inverse Wave Length", Float) = 10 //_InvWaveLength用于控制波长的倒数（_InvWaveLength越大，波长越小）
_Speed ("Speed", Float) = 0.5 //_Speed用于控制河流纹理的移动速度。
}
Subshader {
// Need to disable batching because of the vertex animation
Tags {"Queue"="Transparent" "IgnoreProjector"="True" "RenderType"="Transparent" "DisableBatching"="True"}
//包含了模型空间的顶点动画的Shader,需要取消对该Shader的批处理操作
Pass {
Tags { "LightMode"="ForwardBase" }
ZWrite Off
Blend SrcAlpha OneMinusSrcAlpha
Cull Off //关闭了深度写入，开启并设置了混合模式，并关闭了剔除功能，渲染所有面（双面渲染）。这是为了让水流的每个面都能显示
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
sampler2D _MainTex;
float4 _MainTex_ST;
fixed4 _Color;
float _Magnitude;
float _Frequency;
float _InvWaveLength;
float _Speed;
struct a2v {
float4 vertex : POSITION;
float4 texcoord : TEXCOORD0;
};
struct v2f {
float4 pos : SV_POSITION;
float2 uv : TEXCOORD0;
};
v2f vert(a2v v) {
v2f o;
float4 offset; //计算顶点位移量
offset.yzw = float3(0.0, 0.0, 0.0); //只希望对顶点的x方向进行位移，因此yzw的位移量被设置为0
offset.x = sin(_Frequency * _Time.y + v.vertex.x * _InvWaveLength + v.vertex.y * _InvWaveLength + v.vertex.z * _InvWaveLength) * _Magnitude;
//利用_Frequency属性和内置的_Time.y变量来控制正弦函数的频率
//不同位置具有不同的位移，我们对上述结果加上了模型空间下的位置分量,乘以_InvWaveLength来控制波长
//对结果值乘以_Magnitude属性来控制波动幅度，得到最终的位移。
o.pos = UnityObjectToClipPos(v.vertex + offset); //位移量添加到顶点位置上，再进行正常的顶点变换即可。
o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
o.uv += float2(0.0, _Time.y * _Speed); //纹理动画，即使用_Time.y和_Speed来控制在水平方向上的纹理动画
return o;
}
fixed4 frag(v2f i) : SV_Target {
fixed4 c = tex2D(_MainTex, i.uv);
c.rgb *= _Color.rgb;
return c;
}
ENDCG
}
// Pass to render object as a shadow caster
Pass {
Tags { "LightMode" = "ShadowCaster" }
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#pragma multi_compile_shadowcaster
#include "UnityCG.cginc"
float _Magnitude;
float _Frequency;
float _InvWaveLength;
float _Speed;
struct v2f {
V2F_SHADOW_CASTER;
};
v2f vert(appdata_base v) {
v2f o;
float4 offset;
offset.yzw = float3(0.0, 0.0, 0.0);
offset.x = sin(_Frequency * _Time.y + v.vertex.x * _InvWaveLength + v.vertex.y * _InvWaveLength + v.vertex.z * _InvWaveLength) * _Magnitude;
v.vertex = v.vertex + offset;
TRANSFER_SHADOW_CASTER_NORMALOFFSET(o)
return o;
}
fixed4 frag(v2f i) : SV_Target {
SHADOW_CASTER_FRAGMENT(i)
}
ENDCG
}
}
FallBack "VertexLit"
}随后，创建一个材质球命名为 VertexAnimationWithShadow.mat，并将新编写的着色器赋给该材质。将 main texture 设置为与 WaterMat.mat 使用相同的纹理资源，以保持外观一致。
调整材质面板中的各项参数，使其与 WaterMat.mat 的设置完全相同，确保视觉风格统一。
进入光源的 Light 组件设置，开启阴影功能，并选择软阴影（Soft Shadows）模式，以获得更自然的阴影边缘效果。
将 VertexAnimationWithShadow.mat 材质应用到场景中的 water_full 对象上，使其具备顶点动画及阴影投射能力。
最后，调整 Main Camera 的位置和视野范围，确保画面中能够清晰地观察到水流在平面上投下的动态阴影。
京公网安备 11010802022788号
