200论坛币求怎样定义P值输出的位数

请问高手，怎样定义P值输出的位数，如下两个程序步，怎样定义他们的P值输出位数，谢谢高手指点！

proc npar1way wilcoxon;
  var x;
  class c;
run;


proc ttest;
var x;
class c;
run;

法一:
第一個npar1way有output statement
所以可以用最簡單的方法
proc npar1way wilcoxon;
  var x;
  class c;
  output out=aa;
run;
proc print data=aa;
format PR_WIL P2_WIL PTR_WIL PT2_WIL P_KW 12.9;
run;
第二個ttest沒有output的statement
可以使用ods的statement
ods trace on;
proc ttest data=test;
var x;
class c;
run;
ods trace off;
run;
先去Log裡看每個表單的名稱如下
Output Added:
-------------
Name:       TTests
Label:      T-Tests
Template:   Stat.TTest.TTests
Path:       Ttest.x.TTests
可以知道你的TTest表的名稱
法二
可以用ods將檢定表格輸出如下
proc ttest data=test;
var x;
class c;
ods output TTests=bb;
run;
proc print data=bb;
format probt 12.9;
run;
法三:
利用proc template修改ttest的表格內容再執行一次ttest如下
proc template;
    edit Stat.TTest.TTests;
        edit Probt;
            format = 12.9;
        end;  
    end;
run;
proc ttest data=test;
var x;
class c;
run;

/* this works for TTest */

proc template;         /* add and run this before t-test */
   define column Common.PValue;
            format = pvalue4.2;                     /* this can be changed as format=pvalue5.3 */
   end;
run;

proc ttest  data = sashelp.class;
   var weight;
   class sex;
run;

ODS PATH SASHELP.TMPLMST(READ);    /* restore to the default template setting */

ariman911 发表于 2013-4-29 23:31
法一:
第一個npar1way有output statement
所以可以用最簡單的方法

对于第三种方法修改ttest表格内容，不知如何才能恢复到默认设置，是也用楼上的ODS PATH SASHELP.TMPLMST(READ); 语句吗？谢谢！

楼上的问提很好。 我理解这样的，不一定准确。

沙发里最后一句:   ODS PATH SASHELP.TMPLMST(READ); 是后来加上的。

前面的define 语句实际是新定义了一个column的格式， 并没有修改sas default的输出格式。

而新定义的格式有使用优先权。 所以后面遇到输出pvalue时就会使用这个格式。

最后一句实际上只是恢复使用default的输出格式。

没有试过 edit （修改）sas default template. 感觉修改后的 template,
用 ODS PATH SASHELP.TMPLMST(READ); 语句是不可以恢复的，只能修改回去。

建议在 edit 前要先做一个备份。
default template 的文件名是 tmplmst.sas7bitm，可一在下面的folder里找到。

C:\Program Files\sasroot\core\sashelp.

那是我以前從SUGI看到的
下面是原始文章
http://www.nesug.org/proceedings/nesug06/po/po09.pdf

可以问一下ods trace on 是什么意思?谢谢！！

lnlhckao123 发表于 2013-5-1 21:20
可以问一下ods trace on 是什么意思?谢谢！！

一般一个proc步都会在output中产生多个object，而你想将其中某一部分或一个object输出到数据集中，就需要用ods output object_name=yourdataset， ods trace on能够帮你追踪到每个object所对应的object_name，不知道讲清楚没有，希望对lz有帮助

proc template;        
   define column Common.PValue;
            format = pvalue4.2;                  
   end;
run;
请问，define ；语句是什么意思？谢谢高手！
         end；

lnlhckao123 发表于 2013-5-1 21:20
可以问一下ods trace on 是什么意思?谢谢！！

这是ODS输出（默认listing，9.3默认html可修改）控制的一个应用。trace用来用来获取所有的输出对象。
ods trace on 开始使用/打开这一功能；
ods off off 停止使用/关闭该功能。
http://www.cnblogs.com/colipso/archive/2013/01/27/2878551.html