sas追问2

数据第一步已经变成如下的形式： 城市  区域       板块                               规交1       上海  宝山  大华板块              7号线,737,738,11号线,58,78 上海  嘉定  嘉定新城板块         3号线,嘉环二线,11号线 现在要变成如下形式： 城市  区域       板块          规交1     规交2      规交3     规交4     规交5   规交6 上海  宝山  大华板块         7号线    737          738       11号线    58        78 上海  嘉定  嘉定新城板块    3号线  嘉环二线 11号线 把逗号作为分隔符，每个交通工具都放在一格里。

data a;
input city :$8. distr :$8. bk :$20. gj :$100.;
cards;
上海  宝山  大华板块            7号线,737,738,11号线,58,78
上海  嘉定  嘉定新城板块        3号线,嘉环二线,11号线
;
run;

proc sql ;
        select max(countc(gj,','))+1 into :maxline
        from a;
quit;

data b;
        set a;
        array line(&maxline)  $20.;
        do i = 1 to countc(gj,',')+1;
                line(i) = scan(gj,i,',');
                if i = countc(gj,',')+1 then output;
        end;
        drop i;
run;

数据第一步已经变成如下的形式：


城市  区域       板块                               规交1      
上海  宝山  大华板块              7号线,737,738,11号线,58,78
上海  嘉定  嘉定新城板块         3号线,嘉环二线,11号线

现在要变成如下形式：

城市  区域       板块          规交1     规交2      规交3     规交4     规交5   规交6
上海  宝山  大华板块         7号线    737          738       11号线    58        78
上海  嘉定  嘉定新城板块    3号线  嘉环二线 11号线

把逗号作为分隔符，每个交通工具都放在一格里。


顶！！！！！！！

data a;
input city :$8. distr :$8. bk :$20. gj :$100.;
cards;
上海  宝山  大华板块            7号线,737,738,11号线,58,78
上海  嘉定  嘉定新城板块        3号线,嘉环二线,11号线
;
run;
data b;set a end=lst;
n=compress(gj,',','k');
m=count(n,',')+1;
if _N_=1 then max=m;
retain max;
if m>max then max=m;
if lst then call symput('max',left(max));
drop n m;
run;
data c;set b;
array gjs(&max.) $10.;
do i=1 to &max.;
     gjs(i)=scan(gj,i,',');
end;
drop  i max gj;
run;

你的太阳 发表于 2013-7-28 17:35
data a;
input city :$8. distr :$8. bk :$20. gj :$100.;
cards;

thx！！！

不错啊，学习~

option nodate pagesize=60 linesize=80;

data a;
input city :$8. distr :$8. bk :$20. gj :$100.;
cards;
上海  宝山  大华板块            7号线,737,738,11号线,58,78
上海  嘉定  嘉定新城板块        3号线,嘉环二线,11号线
;
run;

data b;
  set a;
  gj1=substr(gj,1,index(gj,',')-1);
  mid1=substr(gj,index(gj,',')+1);
  gj2=substr(mid1,1,index(mid1,',')-1);
  mid2=substr(mid1,index(mid1,',')+1);
  gj3=substr(mid2,1,index(mid2,',')-1);
  mid3=substr(mid2,index(mid2,',')+1);
   gj4=substr(mid3,1,index(mid3,',')-1);
  mid4=substr(mid3,index(mid3,',')+1);
   gj5=substr(mid4,1,index(mid4,',')-1);
  mid5=substr(mid4,index(mid4,',')+1);
   gj6=substr(mid5,1,index(mid5,',')-1);
  mid6=substr(mid5,index(mid5,',')+1);
  drop gj mid1 mid2 mid3 mid4 mid5 mid6;
run;
proc print data=b;
run;

我是来学习的，笨办法，打个酱油

jolterheadmmtt 发表于 2013-7-30 00:30
option nodate pagesize=60 linesize=80;

data a;

thx！！！