SAS基础宏之16：GetStatsForTable

是 否 +2 论坛币

k人 参与回答

经管之家送您一份

应届毕业生专属福利!

求职就业群

赵安豆老师微信：zhaoandou666

经管之家联合CDA

送您一个全额奖学金名额~ !

立即领取

感谢您参与论坛问题回答

经管之家送您两个论坛币！

+2 论坛币

宏作用

---

这个宏主要是用proc means求一系列统计量的

后来又加了些我自己做的统计量计算，如半方量、几何平均值和连乘积等

用这类宏的好处就是方便调用，因为SAS各个过程的可自定义的东西比较多，经常忘

我现在能比较熟练使用的过程就proc sql了

1. %macro GetStatsForTable(SourceTable,TargetTable,ByFactors,InputVar,InputVarType,OutputVarType,Weight,Statistic);
   
2. 
   
3. /**********************************************************************/
   
4. /* 此宏计算所选变量的统计指标。其中SourceTable是含有所选变量的原始表 */
   
5. /* 格；TargetTable是结果表格；ByFactors是对统计量进行分组研究的分组变 */
   
6. /* 量，没有分组变量时可设置为空；InputVar是进行统计的目标变量，若需要 */
   
7. /* 统计全部变量、全部数值变量和全部字符变量，可分别设为_ALL_、 */
   
8. /* _NUMERIC_和_CHARACTER_；InputVarType是目标变量的类型，当Statistic= */
   
9. /* GMEAN时必须设置，=P表示价格变量，=R表示收益率变量；OutputVarType是 */
   
10. /* 输出变量的类型，=Origin表示不作处理，即输出变量名称等于目标变量的 */
    
11. /* 名称，并用_STAT_变量区分不同的统计量，=Suffix表示输出变量用不同的 */
    
12. /* 统计量作为后缀；Weight是权重变量；Statistic是指定的统计量，=All时 */
    
13. /* 同时计算N|MIN|MAX|MEAN|STD，也可以单独设置，可以设置的统计量如下所 */
    
14. /* 示： */
    
15. /* */
    
16. /* - Descriptive statistics keyword */
    
17. /* CSS RANGE CV SKEW KURT STD LCLM STDERR MAX SUM MEAN GMEAN(Geo- */
    
18. /* metric Mean) GSUM(Continued Product) SUMWGT MIN */
    
19. /* UCLM MODE USS N VAR SVAR(Semi-Variance) NMISS */
    
20. /* - Quantile statistics keyword */
    
21. /* MEDIAN P1 P5 P10 P25 P50 P75 P90 P95 P99 Q1 Q3 QRANGE */
    
22. /* - Hypothesis testing keyword */
    
23. /* PRT T */
    
24. /* */
    
25. /* 最终得到的是含有统计结果的结果表格&TargetTable。 */
    
26. /* */
    
27. /* Created on 2012.12.25 */
    
28. /* Modified on 2013.4.28 */
    
29. /**********************************************************************/
    
30. 
    
31. /* 检查TargetTable的存在性，若不存在则设为&SourceTable */
    
32. %if &TargetTable EQ %STR() %then %let TargetTable=&SourceTable;
    
33. 
    
34. /* 检查ByFactors的存在性 */
    
35. %if &ByFactors NE %STR() %then %do;
    
36. %ChkVar(SourceTable=&SourceTable,InputVar=&ByFactors,FlagVarExists=GSFT_FlagVarExists1);
    
37. 
    
38. %if %SYSFUNC(FIND(&GSFT_FlagVarExists1,0)) NE 0 %then %do;
    
39. %put ERROR: The ByFactors "%SCAN(&ByFactors,%SYSFUNC(FIND(&GSFT_FlagVarExists1,0)))" does not exist in SourceTable, please check it again.;
    
40. %goto exit;
    
41. %end;
    
42. 
    
43. /* 逗号分隔的ByFactors_Comma用于SQL语句 */
    
44. %local ByFactors_Comma;
    
45. 
    
46. %if %SYSFUNC(FIND(&ByFactors,%STR( ))) NE 0 %then %do;
    
47. %let ByFactors_Comma=%SYSFUNC(TRANWRD(%SYSFUNC(COMPBL(&ByFactors)),%STR( ),%STR(,)));
    
48. %end;
    
49. %else %do;
    
50. %let ByFactors_Comma=&ByFactors;
    
51. %end;
    
52. %end;
    
53. 
    
54. 
    
55. /* 检查InputVar的存在性 */
    
56. %if %SYSFUNC(FIND(&InputVar,%STR(:))) NE 0 %then %do;
    
57. %GetVarListForTable(SourceTable=&SourceTable,
    
58. TargetTable=,
    
59. OutputVar=GSFT_InputVar,
    
60. VarType=&InputVar);
    
61. 
    
62. %let InputVar=&GSFT_InputVar;
    
63. %end;
    
64. 
    
65. %if %UPCASE(&InputVar) NE _ALL_ AND %UPCASE(&InputVar) NE _NUMERIC_ AND %UPCASE(&InputVar) NE _CHARACTER_ %then %do;
    
66. %ChkVar(SourceTable=&SourceTable,InputVar=&InputVar,FlagVarExists=GSFT_FlagVarExists2);
    
67. 
    
68. %if %SYSFUNC(FIND(&GSFT_FlagVarExists2,0)) NE 0 %then %do;
    
69. %put ERROR: The InputVar %SCAN(&InputVar,%SYSFUNC(FIND(&GSFT_FlagVarExists2,0))) does not exist in SourceTable, please check it again.;
    
70. %goto exit;
    
71. %end;
    
72. %end;
    
73. 
    
74. /* 检查InputVarType的合法性 */
    
75. %if %UPCASE(&Statistic) EQ GMEAN %then %do;
    
76. %if (%UPCASE(&InputVarType) NE P) AND (%UPCASE(&InputVarType) NE R) %then %do;
    
77. %put ERROR: The InputVarType should be P or R, case insensitive and without quotes.;
    
78. %goto exit;
    
79. %end;
    
80. %end;
    
81. 
    
82. /* 拆分InputVar */
    
83. %SeparateString(InputString=&InputVar,OutputString=GSFT_InputVar);
    
84. 
    
85. /* 检查OutputVarType的合法性 */
    
86. %if &OutputVarType EQ %STR() %then %let OutputVarType=Origin;
    
87. 
    
88. %if (%UPCASE(&OutputVarType) NE ORIGIN) AND (%UPCASE(&OutputVarType) NE SUFFIX) %then %do;
    
89. %put ERROR: The OutputVarType should be Origin or Suffix, case insensitive and without quotes.;
    
90. %goto exit;
    
91. %end;
    
92. 
    
93. /* 检查Weight的唯一性和存在性 */
    
94. %if %SYSFUNC(FIND(&Weight,%STR( ))) NE 0 %then %do;
    
95. %put ERROR: There should be only one Weight, please check it again.;
    
96. %goto exit;
    
97. %end;
    
98. 
    
99. %if &Weight NE %STR() %then %do;
    
100. %ChkVar(SourceTable=&SourceTable,InputVar=&Weight,FlagVarExists=GSFT_FlagVarExists3);
     
101. 
     
102. %if %SYSFUNC(FIND(&GSFT_FlagVarExists3,0)) NE 0 %then %do;
     
103. %put ERROR: The Weight "&Weight" does not exist in SourceTable, please check it again.;
     
104. %goto exit;
     
105. %end;
     
106. %end;
     
107. 
     
108. /* 检查Statistic的唯一性 */
     
109. %if %SYSFUNC(FIND(&Statistic,%STR( ))) NE 0 %then %do;
     
110. %put ERROR: There should be only one Statistic, please check it again.;
     
111. %goto exit;
     
112. %end;
     
113. 
     
114. /* 确认指定的统计量，N|MIN|MAX|MEAN|STD为StatGroup1，其他非特殊统计量为StatGroup2，SVAR为Group3，GMEAN为Group4 */
     
115. %let Statistic=%UPCASE(&Statistic);
     
116. %let GSFT_StatGroup1=%PrxMatch(InputString=&Statistic,PrxString=/((?<!\w)N(?!\w))|(MIN)|(MAX)|((?<!\w)MEAN(?!\w))|(STD)|(ALL)/);
     
117. /* 将正则表达式GSFT_StatGroup2分拆成两段，以免报错 */
     
118. %let GSFT_StatGroup2a=%PrxMatch(InputString=&Statistic,PrxString=/(CSS)|(RANGE)|(CV)|(SKEW)|(KURT)|(LCLM)|(STDERR)|((?<!\w)SUM(?!\w))|(SUMWGT)|(UCLM)|(MODE)|(USS)|((?<!\w)VAR(?!\w))|(NMISS)|(MEDIAN)/);
     
119. %let GSFT_StatGroup2b=%PrxMatch(InputString=&Statistic,PrxString=/(Q1)|(Q3)|(P1(?!0))|(P5)|(P10)|(P25)|(P50)|(P75)|(P90)|(P95)|(P99)|(QRANGE)|(PRT)|((?<!\w)T(?!\w))/);
     
120. %let GSFT_StatGroup3=%PrxMatch(InputString=&Statistic,PrxString=/(SVAR)/);
     
121. %let GSFT_StatGroup4=%PrxMatch(InputString=&Statistic,PrxString=/(GMEAN|GSUM)/);
     
122. 
     
123. %if &GSFT_StatGroup1 EQ 0 AND &GSFT_StatGroup2a EQ 0 AND &GSFT_StatGroup2b EQ 0 AND &GSFT_StatGroup3 EQ 0 AND &GSFT_StatGroup4 EQ 0 %then %do;
     
124. %put ERROR: The Statistic should be assigned properly, please check it again.;
     
125. %goto exit;
     
126. %end;
     
127. 
     
128. /* 开始进行计算 */
     
129. /* 第一步：得到统计量 */
     
130. /* 情形一：计算第一组统计量 */
     
131. %if &GSFT_StatGroup1 NE 0 %then %do;
     
132. %if &ByFactors NE %STR() %then %do;
     
133. proc sort data=&SourceTable;
     
134. by &ByFactors;
     
135. run;
     
136. 
     
137. proc means data=&SourceTable noprint;
     
138. by &ByFactors;
     
139. var &InputVar;
     
140. weight &Weight;
     
141. output out=GSFT_temp;
     
142. run;
     
143. %end;
     
144. %else %do;
     
145. proc means data=&SourceTable noprint;
     
146. var &InputVar;
     
147. weight &Weight;
     
148. output out=GSFT_temp;
     
149. run;
     
150. %end;
     
151. 
     
152. data &TargetTable;
     
153. set GSFT_temp;
     
154. %if &Statistic NE ALL %then %do;
     
155. if _stat_="&Statistic." then output &TargetTable;
     
156. %end;
     
157. run;
     
158. %end;
     
159. /* 情形二：计算第二组统计量 */
     
160. %else %if &GSFT_StatGroup2a NE 0 OR &GSFT_StatGroup2b NE 0 %then %do;
     
161. %if &ByFactors NE %STR() %then %do;
     
162. proc sort data=&SourceTable;
     
163. by &ByFactors;
     
164. run;
     
165. 
     
166. proc means data=&SourceTable noprint;
     
167. by &ByFactors;
     
168. var &InputVar;
     
169. weight &Weight;
     
170. output out=GSFT_temp &Statistic.=;
     
171. run;
     
172. 
     
173. data &TargetTable;
     
174. retain &ByFactors _TYPE_ _FREQ_ _STAT_ &InputVar;
     
175. set GSFT_temp;
     
176. _STAT_="&Statistic.";
     
177. run;
     
178. %end;
     
179. %else %do;
     
180. proc means data=&SourceTable noprint;
     
181. var &InputVar;
     
182. weight &Weight;
     
183. output out=GSFT_temp &Statistic.=;
     
184. run;
     
185. 
     
186. data &TargetTable;
     
187. retain &ByFactors _TYPE_ _FREQ_ _STAT_ &InputVar;
     
188. set GSFT_temp;
     
189. _STAT_="&Statistic.";
     
190. run;
     
191. %end;
     
192. %end;
     
193. /* 情形三：计算第三组统计量，SVAR，即半方差 */
     
194. %else %if &GSFT_StatGroup3 NE 0 %then %do;
     
195. /* 逗号分隔的ByFactors_Comma用于SQL语句 */
     
196. %if %SYSFUNC(FIND(&ByFactors,%STR( ))) NE 0 %then %do;
     
197. %let ByFactors_Comma=%SYSFUNC(TRANWRD(%SYSFUNC(COMPBL(&ByFactors)),%STR( ),%STR(,)));
     
198. %end;
     
199. %else %let ByFactors_Comma=&ByFactors;
     
200. 
     
201. /* 第一步：计算分组均值 */
     
202. proc sql noprint;
     
203. create table GSFT_Mean as
     
204. select *,Count(*) as _FREQ_,
     
205. %do GSFT_i=1 %to &GSFT_InputVar_Num;
     
206. (mean(&&GSFT_InputVar_Var&GSFT_i.)) as &&GSFT_InputVar_Var&GSFT_i.._Mean
     
207. %if &GSFT_i NE &GSFT_InputVar_Num %then %do;
     
208. ,
     
209. %end;
     
210. %end;
     
211. from &SourceTable
     
212. %if &ByFactors NE %STR() %then %do;
     
213. group by &ByFactors_Comma
     
214. %end;
     
215. ;
     
216. quit;
     
217. 
     
218. /* 第二步：计算分组半离差平方 */
     
219. data GSFT_SqrDev;
     
220. set GSFT_Mean;
     
221. %do GSFT_j=1 %to &GSFT_InputVar_Num;
     
222. if &&GSFT_InputVar_Var&GSFT_j LT &&GSFT_InputVar_Var&GSFT_j.._Mean then &&GSFT_InputVar_Var&GSFT_j.._SqrDev=(&&GSFT_InputVar_Var&GSFT_j..-&&GSFT_InputVar_Var&GSFT_j.._Mean)**2;
     
223. else &&GSFT_InputVar_Var&GSFT_j.._SqrDev=0;
     
224. %end;
     
225. run;
     
226. 
     
227. /* 第三步：计算分组半方差 */
     
228. proc sql noprint;
     
229. create table &TargetTable as
     
230. select distinct
     
231. %if &ByFactors NE %STR() %then %do;
     
232. &ByFactors_Comma,
     
233. %end;
     
234. _FREQ_,
     
235. %do GSFT_k=1 %to &GSFT_InputVar_Num;
     
236. sum(&&GSFT_InputVar_Var&GSFT_k.._SqrDev)/_FREQ_ as &&GSFT_InputVar_Var&GSFT_k
     
237. %if &GSFT_k NE &GSFT_InputVar_Num %then %do;
     
238. ,
     
239. %end;
     
240. %end;
     
241. from GSFT_SqrDev
     
242. %if &ByFactors NE %STR() %then %do;
     
243. group by &ByFactors_Comma
     
244. %end;
     
245. ;
     
246. quit;
     
247. 
     
248. data &TargetTable;
     
249. retain &ByFactors _TYPE_ _FREQ_ _STAT_ &InputVar;
     
250. set &TargetTable;
     
251. _TYPE_=0;
     
252. _STAT_='SVAR';
     
253. run;
     
254. %end;
     
255. /* 情形四：计算第四组统计量，GMEAN（几何平均值）和GSUM（连乘积） */
     
256. %else %if &GSFT_StatGroup4 NE 0 %then %do;
     
257. %if %UPCASE(%SUBSTR(&InputVarType,1,1)) EQ P %then %do; /* 仅对InputVarType的首字母进行判断，P可代表Price/PNL */
     
258. proc sql noprint;
     
259. create table &TargetTable as
     
260. select distinct
     
261. %if &ByFactors NE %STR() %then %do;
     
262. &ByFactors_Comma,
     
263. %end;
     
264. %if %UPCASE(&Statistic) EQ GMEAN %then %do;
     
265. %do GSFT_i=1 %to &GSFT_InputVar_Num;
     
266. (exp(sum(log(&&GSFT_InputVar_Var&GSFT_i))))**(1/COUNT(*)) as &&GSFT_InputVar_Var&GSFT_i
     
267. %if &GSFT_i NE &GSFT_InputVar_Num %then %do;
     
268. ,
     
269. %end;
     
270. %end;
     
271. %end;
     
272. %else %if %UPCASE(&Statistic) EQ GSUM %then %do;
     
273. %do GSFT_j=1 %to &GSFT_InputVar_Num;
     
274. (exp(sum(log(&&GSFT_InputVar_Var&GSFT_j)))) as &&GSFT_InputVar_Var&GSFT_j
     
275. %if &GSFT_j NE &GSFT_InputVar_Num %then %do;
     
276. ,
     
277. %end;
     
278. %end;
     
279. %end;
     
280. from &SourceTable
     
281. %if &ByFactors NE %STR() %then %do;
     
282. group by &ByFactors_Comma
     
283. %end;
     
284. ;
     
285. quit;
     
286. %end;
     
287. %else %if %UPCASE(%SUBSTR(&InputVarType,1,1)) EQ R %then %do;
     
288. proc sql noprint;
     
289. create table &TargetTable as
     
290. select distinct
     
291. %if &ByFactors NE %STR() %then %do;
     
292. &ByFactors_Comma,
     
293. %end;
     
294. %if %UPCASE(&Statistic) EQ GMEAN %then %do;
     
295. %do GSFT_i=1 %to &GSFT_InputVar_Num;
     
296. (exp(sum(log(1+&&GSFT_InputVar_Var&GSFT_i))))**(1/COUNT(*))-1 as &&GSFT_InputVar_Var&GSFT_i
     
297. %if &GSFT_i NE &GSFT_InputVar_Num %then %do;
     
298. ,
     
299. %end;
     
300. %end;
     
301. %end;
     
302. %else %if %UPCASE(&Statistic) EQ GSUM %then %do;
     
303. %do GSFT_j=1 %to &GSFT_InputVar_Num;
     
304. exp(sum(log(1+&&GSFT_InputVar_Var&GSFT_j)))-1 as &&GSFT_InputVar_Var&GSFT_j
     
305. %if &GSFT_j NE &GSFT_InputVar_Num %then %do;
     
306. ,
     
307. %end;
     
308. %end;
     
309. %end;
     
310. from &SourceTable
     
311. %if &ByFactors NE %STR() %then %do;
     
312. group by &ByFactors_Comma
     
313. %end;
     
314. ;
     
315. quit;
     
316. %end;
     
317. %else %do;
     
318. %put ERROR: The parameter InputVarType should be P or R, case insensitive and without quotes.;
     
319. %goto exit;
     
320. %end;
     
321. 
     
322. data &TargetTable;
     
323. retain &ByFactors _TYPE_ _FREQ_ _STAT_ &InputVar;
     
324. set &TargetTable;
     
325. _TYPE_=0;
     
326. %if %UPCASE(&Statistic) EQ GMEAN %then %do;
     
327. _STAT_='GMEAN';
     
328. %end;
     
329. %if %UPCASE(&Statistic) EQ GSUM %then %do;
     
330. _STAT_='GSUM';
     
331. %end;
     
332. run;
     
333. %end;
     
334. 
     
335. /* 第二步：按要求输出表格 */
     
336. %if %UPCASE(&OutputVarType) EQ SUFFIX %then %do;
     
337. proc sql noprint;
     
338. select distinct _STAT_ into :GSFT_StatString separated by ' '
     
339. from &TargetTable;
     
340. quit;
     
341. 
     
342. %SeparateString(InputString=&GSFT_StatString,OutputString=GSFT_StatString);
     
343. 
     
344. data %do GSFT_m=1 %to &GSFT_StatString_Num;
     
345. GSFT_Output_&&GSFT_StatString_Var&GSFT_m(rename=(
     
346. %do GSFT_n=1 %to &GSFT_InputVar_Num;
     
347. &&GSFT_InputVar_Var&GSFT_n..=&&GSFT_InputVar_Var&GSFT_n.._&&GSFT_StatString_Var&GSFT_m
     
348. %end;
     
349. ))
     
350. %end;
     
351. ;
     
352. set &TargetTable;
     
353. %do GSFT_o=1 %to &GSFT_StatString_Num;
     
354. if _STAT_ EQ "&&GSFT_StatString_Var&GSFT_o" then output GSFT_Output_&&GSFT_StatString_Var&GSFT_o;
     
355. %end;
     
356. run;
     
357. 
     
358. data &TargetTable(drop=_STAT_);
     
359. merge %do GSFT_p=1 %to &GSFT_StatString_Num;
     
360. GSFT_Output_&&GSFT_StatString_Var&GSFT_p
     
361. %end;
     
362. ;
     
363. by &ByFactors;
     
364. run;
     
365. %end;
     
366. 
     
367. /* 删除不必要的表格 */
     
368. proc datasets lib=work nolist;
     
369. delete GSFT_:;
     
370. quit;
     
371. 
     
372. %exit:
     
373. %mend;
     
374. 
     
375. 
     
376. %macro Demo();
     
377. 
     
378. %let SourceTable=NavOfFund;
     
379. %let TargetTable=NavOfFund_GMean;
     
380. %let ByFactors=Fund_Code; /* 可设置为多个，用空格分隔 */
     
381. %let InputVar=Adj_NAV Unit_NAV;
     
382. %let InputVarType=; /* 当Statistic=GMEAN时必须设置，=P表示价格变量，=R表示收益率变量 */
     
383. %let OutputVarType=Suffix; /* 输出变量的类型，=Origin表示不作处理，=Suffix表示输出变量用不同的统计量作为后缀 */
     
384. %let Weight=; /* 仅为一个变量 */
     
385. %let Statistic=All; /* 仅为一个统计量 */
     
386. %GetStatsForTable(&SourceTable,&TargetTable,&ByFactors,&InputVar,&InputVarType,&OutputVarType,&Weight,&Statistic);
     
387. 
     
388. /* 计算几何平均收益率的例子，且InputVar变量为价格变量 */
     
389. %let SourceTable=ReturnOfFund_Dy;
     
390. %let TargetTable=ReturnOfFund_GMean;
     
391. %let ByFactors=Fund_Code; /* 可设置为多个，用空格分隔 */
     
392. %let InputVar=Adj_NAV;
     
393. %let InputVarType=P; /* 当Statistic=GMEAN时必须设置，=P表示价格变量，=R表示收益率变量 */
     
394. %let OutputVarType=; /* 输出变量的类型，=Origin表示不作处理，=Suffix表示输出变量用不同的统计量作为后缀 */
     
395. %let Weight=; /* 仅为一个变量 */
     
396. %let Statistic=GMEAN; /* 仅为一个统计量 */
     
397. %GetStatsForTable(&SourceTable,&TargetTable,&ByFactors,&InputVar,&InputVarType,&OutputVarType,&Weight,&Statistic);
     
398. 
     
399. /* 计算几何连乘积的例子，且InputVar变量为收益率变量 */
     
400. %let SourceTable=GARFP_AbnRetOfPort;
     
401. %let TargetTable=GARFP_AbnRetOfPort_GSUM;
     
402. %let ByFactors=Port_Code End_Yr End_Mt; /* 可设置为多个，用空格分隔 */
     
403. %let InputVar=Ret_Dy Ret_Bm AbnRet_Dy AbnRetRatio_Dy;
     
404. %let InputVarType=R; /* 当Statistic=GMEAN时必须设置，=P表示价格变量，=R表示收益率变量 */
     
405. %let OutputVarType=; /* 输出变量的类型，=Origin表示不作处理，=Suffix表示输出变量用不同的统计量作为后缀 */
     
406. %let Weight=; /* 仅为一个变量 */
     
407. %let Statistic=GSUM; /* 仅为一个统计量 */
     
408. %GetStatsForTable(&SourceTable,&TargetTable,&ByFactors,&InputVar,&InputVarType,&OutputVarType,&Weight,&Statistic);
     
409. 
     
410. %mend;

复制代码

扫码加我 拉你入群

请注明：姓名-公司-职位

以便审核进群资格，未注明则拒绝

分享2 收藏4 回帖

关键词：stats Table sas基础 ABLE gets GetStatsForTable SAS 基础宏