请假SAS高手，如何计算日收益率？

数据类型
公司        日期           收盘价
1            19940101      1
1            19940102      5
1            19940103     6
2           19940101      1
2            19940102      5
2           19940103      6

收益率价格计算方法是，（当天收盘价格-昨日收盘价格）/昨日收盘价格

谢谢大家！

PROC SORT DATA = CRACKMAN OUT = A; BY COMPANY DATE; RUN;

DATA B;
   SET A; BY COMPANY;
   DATE_1 = INPUT(PUT(DATE, 10.), YYMMDD10.);
   LAGprice = LAG(PRICE);
   DIF_date_1 = DIF(DATE_1);
   DIF_price = DIF(PRICE);
   IF (NOT FIRST.company) THEN
      IF (DIF_date_1 = 1 AND LAGprice) THEN RATE = DIF_PRICE/LAGprice;
   DROP LAG: DIF: DATE_1;
RUN;

data crackman;
input company date price@;
cards;
1            19940101      1
1            19940102      6
1            19940103     7
2           19940101      1
2            19940102      5
2           19940103      6

;
run;
proc sort data=crackman out=crackman;
by company date;
run;
proc transpose out=crackman1(drop=_name_);
var price;
by company;
id date;
run;
data result;
set crackman1;
array date _19940101-_19940103;
rate1=put(((date(2)/date(1))-1)*100,F8.2)||'%';
rate2= put(((date(3)/date(2))-1)*100,F8.2)||'%';
proc print;
run;

抛砖引玉啊
希望有人能写出宏来
思路都差不多
期待高手写出更好的程序让我学习学习

data a;
input company date price@;
cards;
1            19940101      1
1            19940102      6
1            19940103     7
2           19940101      1
2            19940102      5
2           19940103      6

;
run;

data b;
set a;
by company;
price_lag=lag(price);

if not first.company then rate=(price-price_lag)/price_lag;
else rate=.;
run;

如果有1000家公司怎么算？

data a;
input number date price;
cards;
1            19940101      1
1            19940102      5
1            19940103     6
2           19940101      1
2            19940102      5
2           19940103      6
;

data b;
        set a;
        by number;
        dif_price=dif(price);lag_price=lag(price);
        if first.number then rate=.;
            else rate=dif_price/lag_price;
run;