【求教】关于SAS循环中输出每次循环计算结果的问题 [推广有奖]

data test;
   do i=1 to 10;
      do j=1 to 5;
             x=3*i+8*j;
                 output;
          end;
   end;
run;

多谢，我运行后有点问题，是我没有说清情况，我有一个数据集大概32400行，需要对于每一组i和j从头到尾计算完整个32400行后输出最后的结果，然后再计算下一组i和j。可是现在按照您的方法运行后，是针对所有的i和j组合计算第一行，然后在第二行计算所有的i和j组合。

data have;
   do x=1,3,5,6,7;
     output;
   end;
run;


data want;
   retain y;
   drop x;
   do i=1 to 10;
      do j=1 to 5;
               y=0;
               do obs=1 to nobs;
                      set have point=obs nobs=nobs;
              y=sum(y,x*i+j);
                   end;
                   output;
          end;
   end;
   stop;
run;

data have;
   do x=1,3,5,6,7;
     output;
   end;
run;


data want;
   set have end=last;
   array y(10,5) y1-y50;
   retain y:;
   
   do i=1 to 10;
      do j=1 to 5;
              y(i,j)=sum(y(i,j),x*i+j);
           end;
        end;

        if last then do;
       do i=1 to 10;
              do j=1 to 5;
                     yy=y(i,j);
                         output;
                  end;
           end;
        end;
        keep i j yy;
run;