求助观测汇总连接问题

有如下数据集：

data a;
if _n_<8 then g=1;else g=2;
input x $ @@;
y=dif(x);
cards;
07 12 13 14 15 19 22 23 24 29 30 31 32 36
;run;

想得到如下效果：g=1 result='07,12-15,19,22' ; g=2 result='23-24,29-32,36'
意思就是按照g来分组，将x进行汇总，得到的字符串如有连号，用‘-’连接。

问题貌似不难，但是想了一个晚上，很受打击。。。

貌似按照y=dif(x)可以算，但是感觉写出来会很啰嗦，不知有没有更简洁的办法，我记得前段时间貌似坛子里看到过。。

One way as follow:

data b;set a;
retain z 0;
if y^=1 then z+1;
run;


..... Still have a loooooong way to go .....

data a;
if _n_<11 then g=1;else g=2;
input x $ @@;
y=dif(x);
cards;
07 08 09 12 13 14 15 19 21 22 23 24 29 30 31 32 36
;run;

data c;
   length result $100;
   retain result;
   flag=0;
   do until(y>1 or last.g);
      set a;
          by g x;
          if first.g then result=x;
          if y=1 then do;flag=1; tmp=x;end;
   end;
   if flag=1 then do;
        result=catx("-",result,tmp);
        if not last.g or y>1 then result=catx(", ",result,x);
          end;
   else result=catx(", ",result,x);

   if last.g then output;
   keep g result;
run;

比较常规的方法：
data a;
if _n_<8 then g=1;else g=2;
input x $ @@;
y=dif(x);
cards;
07 12 13 14 15 19 22 23 24 29 30 31 32 36
;run;

data b;
   set a;
   by g;
   length result $100 tmp $8;
   retain flag 0 tmp result;
   if first.g then do; result=x; flag=0; tmp=" "; end;
   else do;
       if y ne 1 then do;
               if flag=0 then result=catx(", ",result,x);
                           else if flag=1 then result=catx(", ",catx("-",result,tmp),x);
                           flag=0;
                        end;
       else if y=1 then do;
               flag=1;
               tmp=x;
                           if last.g then result=catx("-",result,tmp);
            end;
   end;
   if last.g;
   keep g result;
run;

pobel 发表于 2013-10-9 08:16
比较常规的方法：
data a;
if _n_

谢谢pobel，需要很强的逻辑。

pobel 发表于 2013-10-8 23:58
data a;
if _n_1 or last.g);
      set a;

有个问题有点疑惑，可能还是涉及到PDV的问题，

在第一个loop里面，set a在do until里面和在do until之外有什么区别呢？

能不能麻烦讲讲其中的逻辑呢？

是不是第一个do loop就是把flag的值按照y的值全部赋值好以后，然后再进行下面的if else的语句呢

其实，在看你的那个常规方法的时候，那种疑惑更大，
尤其是在那个else do的循环里面，能不能麻烦仔细讲讲那个循环里面的逻辑呢

1. data a;
   
2.     if _n_<8 then g=1;else g=2;
   
3.     input x $ @@;
   
4. cards;
   
5. 07 12 13 14 15 19 22 23 24 29 30 31 32 36
   
6. ;
   
7. 
   
8. data b(keep=g result);
   
9.     length result $100;
   
10.     do until(last.g);
    
11.         set a;
    
12.         by g;
    
13.         _x=input(x,best.);
    
14.         if first.g or _x ne sum(lag(_x),1) then result=cats(catx(',',result,x),'-');
    
15.         else result=prxchange(cats('s/-\d*$/-',x,'/'),1,strip(result));
    
16.     end;
    
17.     result=prxchange(cats('s/-(,)|-$/$1/'),-1,strip(result));
    
18. run;

复制代码