不能用proc freq过程

1. data a;
   
2. input x y;
   
3. cards;
   
4. 1 2
   
5. 1 1
   
6. 1 1
   
7. 2 2
   
8. 2 2
   
9. ;
   
10. run;

复制代码

希望得到的结果
var cat  n
x     1   3
       2   2
y     1   2
       2  3
注意不能用proc freq过程，macro程序中可以用data步和sql过程。

抛砖引玉

proc sql;
create table a1 as
select
       distinct A.x as cat,
       count(A.x) as n,
           'x' as id
from a as A
group by a.x

union all

select
       distinct a.y as cat,
           count(a.y) as n,
           'y' as id
from a as A
group by a.y
;
quit;

%macro cnt;

proc sql noprint;
select name into: varlist separated by " " from dictionary.columns
where libname='WORK' and memname='A';
quit;

%let i=1;
%do %until(%scan(&varlist,&i)=%str( ));
proc sql;
create table a&i as
select "%scan(&varlist,&i)" as var, %scan(&varlist,&i) as cat,count(%scan(&varlist,&i)) as n
from a
group by 1,2;
quit;
%let i=%eval(&i+1);
%end;

%let cnt=%sysfunc(count(&varlist,%str( )));
data combine;
set
%do i=1 %to %eval(&cnt+1);
a&i
%end;
;
run;
%mend;
%cnt

data wanted;
set combine;
by notsorted var;
if not first.var then var='';
run;

1. data _null_;
   
2.     if _n_=1 then do;
   
3.         declare hash h(hashexp:4);
   
4.         rc=h.definekey('var','cat');
   
5.         rc=h.definedata('var','cat','n');
   
6.         rc=h.definedone();
   
7.     end;
   
8.     set a end=last;
   
9.     array numarr x y;
   
10.     do over numarr;
    
11.         var=vname(numarr); cat=numarr;
    
12.         n=.; rc=h.find(); n+1;
    
13.         if rc then rc=h.add();
    
14.         else rc=h.replace();
    
15.     end;
    
16.     if last then h.output(dataset:'b');
    
17. run;

复制代码

我就想到简单的分开用proc univariate来做，再把结果set到一起

proc univariate data=a;
class x;
var x ;
output out=b
n=n;
run;

proc univariate data=a;
class y;
var y ;
output out=c
n=n;
run;

data b;
length var $1.;
set b;
var='x';
rename x=cat;
run;

data c;
length var $1.;
set c;
var='y';
rename y=cat;
run;

data d;
set b c;
run;

data b(keep=group cat);
set a;
array newvar _numeric_;
do over newvar;
  group=vname(newvar);
  cat=newvar;
  output;
end;
run;

proc tabulate data=b;
class group cat;
table group='var'*cat,n*f=2.;
run;

hopewell 发表于 2013-12-3 12:44

程序员的惯用做法。。

楼主何其多金也！

You can use proc means as below,

data a;
input x y;
cards;
1 2
1 1
1 1
2 2
2 2
;
proc means data=a ;
class x y;
output out=b(where=(_type_ in (1,2)) rename=(_freq_=n));
run;

proc print data=b;
run;

proc sql;
        create table b as
        select 'x' as var, x as cat, count(*) as n
        from a group by 1, 2
        union
        select 'y' as var, y as cat, count(*) as n
        from a group by 1,2;
quit;