请求如何在data步中用变量代表样本数。

是 否 +2 论坛币

k人 参与回答

经管之家送您一份

应届毕业生专属福利!

求职就业群

赵安豆老师微信：zhaoandou666

经管之家联合CDA

送您一个全额奖学金名额~ !

立即领取

感谢您参与论坛问题回答

经管之家送您两个论坛币！

+2 论坛币

例如:
v1有5个数据。但事先不知道有5个，怎样才能在data步中计算出有5个样本呢?.
data a;
     input v1;
     cards;
     1
     2
     3
     4
     5;

data b;
      set a;
       sum=_n_/5;
这个是个例子。

如果说不知道样本数有多少的话。有没有能自动化的在data步中算出5？

proc summary  data=a;
     var v1;
     output out=c  n=n;
是想过以上这个方法计算出n来。但是不懂得怎么用到里面去。

请教大家教教我。

扫码加我 拉你入群

请注明：姓名-公司-职位

以便审核进群资格，未注明则拒绝

分享0 收藏0 回帖

关键词：data步 Data 样本数 Summary output 样本 变量 请求 Data 代表

input后加个"count+1;"语句试试！

2# 一江明月
/************方法一***********/
data a;
     input v1;
     cards;
     1
     2
     3
     4
     5
;
run;
%symdel n;
data _null_;
call symput('n',nobs);
stop;
set a nobs=nobs;
run;

data b;
      set a;
       sum=_n_/symget("n");
       *sum=_n_/&n;
       run;
      
/********方法二*************/
%let dset=a;
%let dsid = %sysfunc(open(&dset));
%let nobs =%sysfunc(attrn(&dsid,NOBS));
%let rc = %sysfunc(close(&dsid));
%put &nobs;
data b;
      set a;
       sum=_n_/symget("nobs");*取宏变量的值;
       *sum=_n_/&nobs;*直接取宏变量的值;
       run;

/*这是按照你的思路想法，去写的代码元*/
data a;
     input v1;
     cards;
     1
     2
     3
     4
     5
;
proc summary  data=a;
     var v1;
     output out=c  n=n;
run;
data _null_;
set c;
call symput("n",n);
run;
data b;
      set a;
       sum=_n_/&n;
run;

szclx 发表于 2010-1-15 13:24
例如:
v1有5个数据。但事先不知道有5个，怎样才能在data步中计算出有5个样本呢?.
data a;
     input v1;
     cards;
     1
     2
     3
     4
     5;

data b;
      set a;
       sum=_n_/5;
这个是个例子。

如果说不知道样本数有多少的话。有没有能自动化的在data步中算出5？

proc summary  data=a;
     var v1;
     output out=c  n=n;
是想过以上这个方法计算出n来。但是不懂得怎么用到里面去。

请教大家教教我。

Not exactly sue what you want.

If you want to know how many obs in a data set, you don't even need to open it.

SAS stores a data set into two pieces after Version 5 --- the descriptive information or head file and data.

The descriptive information can be accessed in compiling time.

Here is an example.

43
44   data t1;
45     do i= 1 to 5;
46       output;
47     end;
48   run;

NOTE: The data set WORK.T1 has 5 observations and 1 variables.
NOTE: DATA statement used (Total process time):
      real time           0.01 seconds
      cpu time            0.01 seconds


49
50   data _null_;
51     if 0 then set t1 nobs=number_of_obs_on_t1 ;
52     put number_of_obs_on_t1=;
53   run;

number_of_obs_on_t1=5
NOTE: DATA STEP stopped due to looping.
NOTE: DATA statement used (Total process time):
      real time           0.00 seconds
      cpu time            0.00 seconds