请教：如何用把某一变量名相同的观测值合并成同一行

我有如下数据：

Study_ID	A01ab	A02ab	A03ab	A04ab	B01ab	B02ab
1	1	0	0	0	0	0
1	0	0	1	0	0	0
1	0	0	0	0	1	0
2	1	0	0	0	0	0
2	0	1	0	0	0	0

原始数据中A01ab，A02ab，A03ab，A04ab，B01ab，B02ab这些变量的值，每一行只可能有一个值为1
想输出如下结果：

Study_ID	A01ab	A02ab	A03ab	A04ab	B01ab	B02ab
1	1	0	1	0	1	0
2	1	1	0	0	0	0

同一个StudyID的A01ab，A02ab，A03ab，A04ab，B01ab，B02ab这些变量的值同时相加（其实就是取这些变量中所有为1的值）并且输出一行观测值

重新学习array，又写了一遍。

1. data a;
   
2. input study_ID A01ab A02ab A03ab A04ab B01ab B02ab;
   
3. cards;
   
4. 1 1 0 0 0 0 0
   
5. 1 1 0 1 0 0 0
   
6. 1 1 0 1 0 1 0
   
7. 2 1 0 0 0 0 0
   
8. 2 0 1 0 0 0 0
   
9. ;
   
10. run;
    
11. 
    
12. proc sort data=a out=in;
    
13.         by study_ID;
    
14. run;
    
15. proc print data=in;
    
16. run;
    
17. 
    
18. data out;
    
19.         set in;
    
20.         by study_ID;
    
21.                   array rawvar {*} A01ab A02ab A03ab A04ab B01ab B02ab; /* Re-define the raw variables as elements of an array */
    
22.                   array newvar {*} A01 A02 A03 A04 B01 B02; /* Define the new variables as elements of an array */
    
23.                                   do i = 1 to dim(rawvar);
    
24.                                         if first.study_ID then do; /* Create a new variable and assign an initial value of 0 at each first record of sutdy_ID*/
    
25.                                                 newvar{i} = 0;
    
26.                                         end;
    
27.                                         newvar{i} + rawvar{i}; /* SUM statement, hold the value of last row and then add the value of corresponding raw variable */
    
28.                                         if newvar{i} ^= 0 then newvar{i} = 1;
    
29.                                   end;
    
30.                   if last.study_ID then output;
    
31.         keep A01 -- B02;
    
32. run;
    
33. 
    
34. proc print data=out;        
    
35. run;

复制代码

我的编程思路大致如下：

• 因为最后只要individual level的数据集，而原始数据集的结构属于“multipl rows for an individual”，可以使用 LAST. 功能在每一组的最后一行输出到数据集即可。
• 利用 DATA 步按行循环处理的原理，对各列进行累计加总。一旦每组最后一行的累加值大于0，即说明该列中有取值为 1 的情况。因为需要累加，所以用到了 SUM 语句。建议先不加“ if last.study_ID then output; ” 这一句，查看生成的数据集是否正确，以便验证编程的逻辑。
• 最后按需整理数据集，保留所需变量。
  

数据输入代码如下
data a;
input study_ID A01ab A02ab A03ab A04ab B01ab B02ab;
cards;
1 1 0 0 0 0 0
1 0 0 1 0 0 0
1 0 0 0 0 1 0
2 1 0 0 0 0 0
2 0 1 0 0 0 0
;

SAS小白，还望各位大神不吝赐教感谢！

供参考：proc report data=a;
column study_ID (A01ab A02ab A03ab A04ab B01ab B02ab),sum;
define  study_ID/group;
ods output report=work.b(drop=_break_);
run;

1. data a;
   
2. input study_ID A01ab A02ab A03ab A04ab B01ab B02ab;
   
3. cards;
   
4. 1 1 0 0 0 0 0
   
5. 1 0 0 1 0 0 0
   
6. 1 0 0 0 0 1 0
   
7. 2 1 0 0 0 0 0
   
8. 2 0 1 0 0 0 0
   
9. ;
   
10. run;
    
11. 
    
12. proc sort data=a out=in;
    
13.         by study_ID;
    
14. run;
    
15. 
    
16. data out;
    
17.         set in;
    
18.         by study_ID;
    
19.         if first.study_ID then do;
    
20.                 A01 = 0;
    
21.                 A02 = 0;
    
22.                 A03 = 0;
    
23.                 A04 = 0;
    
24.                 B01 = 0;
    
25.                 B02 = 0;
    
26.         end;
    
27.         A01 + A01ab;
    
28.         A02 + A02ab;
    
29.         A03 + A03ab;
    
30.         A04 + A04ab;
    
31.         B01 + B01ab;
    
32.         B02 + B02ab;
    
33.         if A01 ^= 0 then A01 = 1;
    
34.         if A02 ^= 0 then A02 = 1;
    
35.         if A03 ^= 0 then A03 = 1;
    
36.         if A04 ^= 0 then A04 = 1;
    
37.         if        B01 ^= 0 then B04 = 1;
    
38.         if B02 ^= 0 then B02 = 1;
    
39.         if last.study_ID then output;
    
40.         keep A01 -- B02;
    
41. run;
    
42. 
    
43. proc print data=out;       
    
44. run;

复制代码

代码有些长。肯定是可以有更简短的写法的，比如用数组。可是数组的用法还不是很熟悉，看有没有高手来修改一下使它变得更短。

逍遥梦蝶 发表于 2020-4-20 18:31
重新学习array，又写了一遍。

谢谢大神指点思路，我自己用了你说的第一种方法，但是还是想学习一下数组的运用，正好你解决了我的疑惑，再次感谢

基于每一行只可能有一个值为1原则;
data a;
input study_ID A01ab A02ab A03ab A04ab B01ab B02ab;
cards;
1 1 0 0 0 0 0
1 0 0 1 0 0 0
1 0 0 0 0 1 0
2 1 0 0 0 0 0
2 0 1 0 0 0 0
;
run;

proc sql noprint;
        create table b as
        select study_ID,sum(A01ab) as A01ab,sum(A02ab) as A02ab,sum(A03ab) as A03ab,sum(A04ab) as A04ab,sum(B01ab) as B01ab,sum(B02ab) as B02ab
        from a
        group by study_ID;
run;

1. data a;
   
2. input study_ID $ A01ab A02ab A03ab A04ab B01ab B02ab;
   
3. cards;
   
4. 1 1 0 0 0 0 0
   
5. 1 0 0 1 0 0 0
   
6. 1 0 0 0 0 1 0
   
7. 2 1 0 0 0 0 0
   
8. 2 0 1 0 0 0 0
   
9. ;
   
10. run;
    
11. 
    
12. proc sql;
    
13.         create table b as
    
14.         select distinct study_id, sum(A01ab) as A01ab, sum(A02ab) as A02ab, sum(A03ab) as A03ab,
    
15.                                         sum(A04ab) as A04ab, sum(B01ab) as B01ab, sum(B02ab) as B02ab
    
16.         from a
    
17.         group by study_id
    
18.         ;
    
19. quit;

复制代码

data a;
input study_ID $ A01ab A02ab A03ab A04ab B01ab B02ab;
cards;
1 1 0 0 0 0 0
1 0 0 1 0 0 0
1 0 0 0 0 1 0
2 1 0 0 0 0 0
2 0 1 0 0 0 0
;
run;

proc sort data=a;
        by study_id;
run;

data b;
        set a;
        by study_id;
        array var A01ab A02ab A03ab A04ab B01ab B02ab;
        array _t{6};
        retain _t1-_t6;
        do i=1 to 6;
                if first.study_id then _t[i]=0;
                if var[i]=1 then _t[i]=1;
                if last.study_id then do;
                        var[i]=_t[i];
                end;
        end;
        if last.study_id;
        drop _t: i;
run;