关于SAS和R两个统计包数据交流的一个例子

是 否 +2 论坛币

k人 参与回答

经管之家送您一份

应届毕业生专属福利!

求职就业群

赵安豆老师微信：zhaoandou666

经管之家联合CDA

送您一个全额奖学金名额~ !

立即领取

感谢您参与论坛问题回答

经管之家送您两个论坛币！

+2 论坛币

最近我看了一篇SAS与R做数据交流的文章，对程序做了一些调整，实现了由SAS整理数据集，然后调用R统计包进行作图，之后再传入SAS，并通过ODS以网页格式呈现，现放此供大家参考使用，，因为前阵子看到了很多讨论SAS和R这两个统计包未来发展趋势的帖子，遂了解了一下，程序及简单注释贴于以下：
                                                                         1，数据集准备及整理
LIBNAME new 'e:\temp\new';
PROC datasets LIB=new KILL;
RUN;
QUIT;
DATA sasuser.v_prdsale / VIEW = sasuser.v_prdsale;
SET sashelp.prdsale;
LENGTH yyq $6;
yyqtr = year + (quarter - 1)/4;
mon = MONTH(month);
yyq = PUT(month, YYQ6.);
yq = INTCK('QTR', '31dec1992'd, month);
SELECT (country);
WHEN ('U.S.A.') cntry = 'USA';
WHEN ('GERMANY') cntry = 'DE';
WHEN ('CANADA') cntry = 'CA';
OTHERWISE;
END;
RUN;
PROC SUMMARY DATA=sasuser.v_prdsale MISSING NWAY;
CLASS cntry yq product;
VAR actual;
OUTPUT OUT=new.prdsale SUM=;
RUN;

%MACRO exportlib(lib, outdir, tempdir);
OPTIONS NOFMTERR;
PROC COPY IN=&lib OUT=work;
RUN;
PROC CONTENTS DATA=work._ALL_ NOPRINT
OUT=_contents_(KEEP=memname memlabel name type label format length
nobs);
RUN;
PROC EXPORT DATA=_contents_ OUTFILE="&outdir/_contents_.csv" REPLACE;
RUN;
DATA _NULL_;
SET _contents_;
BY memname;
FILE "&tempdir/_export_.sas";
RETAIN bk -1;
IF FIRST.memname & (nobs > 0) THEN DO;
PUT 'DATA ' memname ';';
PUT ' SET ' memname ';';
PUT ' FORMAT _NUMERIC_ BEST14.;';
PUT 'RUN;';
PUT 'PROC EXPORT DATA=' memname;
PUT ' OUTFILE="' "&outdir/" memname +bk '.csv"';
PUT ' REPLACE;';
PUT 'RUN;';
END;
RUN;
%INCLUDE "&tempdir/_export_.sas";
%MEND exportlib;
%exportlib(new, e:/temp/r, e:/t);
run;
                                                                         2，准备R统计包产生图形的脚本程序
DATA _NULL_;
FILE 'e:\temp\r\program.r' LRECL=1024;
PUT 'library(Hmisc)';
PUT 'library(survival)';
PUT 'library(splines)';
PUT 'library(lattice)';
PUT 'library(grDevices)';
PUT "sasdata <- sasxport.get('e:/temp/r', method=c('csv'))";
PUT "jpeg('e:/temp/r/p.jpg')";
PUT 'xyplot(actual~ yq | cntry*product';
PUT ' ,data=sasdata';
PUT " ,xlab = 'Quarter'";
PUT " ,ylab = 'Actual Sales'";
PUT ' ,panel = function(x, y) {';
PUT ' panel.grid(h=-1, v=-1)';
PUT ' panel.xyplot(x, y)';
PUT ' panel.loess(x, y';
PUT ' ,span=1';
PUT ' ,degree=2';
PUT ' )';
PUT ' }';
PUT " ,main = 'Plotted using R'";
PUT ' )';
PUT 'dev.off()';
PUT 'q()';
RUN;
                                                                         3，此次的路径需要设置为你安装R软件的路径
OPTIONS XWAIT XSYNC;
X "D:\R\R-2.12.1\bin\r.exe --no-save --quiet <""E:\temp\r\program.r";        /*  This command is a problem!  */
run;
                                                                         4，调用ODS
ODS ESCAPECHAR='^';
ODS HTML FILE='e:\temp\r\report.html' STYLE=minimal
GPATH='e:\temp\r' GTITLE GFOOTNOTE;
DATA _NULL_;
FILE PRINT;
PUT "<IMG SRC='e:\temp\r\p.jpg' BORDER='0'>";
RUN;
ODS _ALL_ CLOSE;

不同统计包，如SAS与R，各具有自己擅长之处，对于这两者我都很喜欢，所以花心思琢磨一下它们的交流，请前辈指正。

扫码加我 拉你入群

请注明：姓名-公司-职位

以便审核进群资格，未注明则拒绝

分享0 收藏2 回帖

关键词：SAS和R otherwise contents Survival datasets 文章 统计 程序 网页

好东东 顶一下 呵呵

你的级别很高啊前辈！

很有创意！

把你的SAS程序和结果贴上来让大家看看。

好的！
假设已经建立了相应的文件夹，如E:\temp\new和E:\temp\r以及E:\t，程序跑到宏%exportlib(new, e:/temp/r, e:/t)结束之后，便会在E:\temp\r中产生欲分析的数据集(PRDSALE.csv)，经过下面一个DATA步后，由SAS写了一个R的脚本程序(program.r)，通过X语句执行R脚本：
OPTIONS XWAIT XSYNC;
X "D:\R\R-2.12.1\bin\r.exe --no-save --quiet <""E:\temp\r\program.r";      
run;
运行，在r文件夹里产生了一个JPEG格式的图片及由ODS产生的report.html。

呵呵，第一次弄图片，不知图片是否应该放于附件里，不对请前辈斧正啊！