关于处理SAS的Log文件的宏-经管之家官网！

我经常遇到的问题是想找出成百上千个DATA步和过程步中花费时间最长的步骤
但SAS输出的Log文件可读性不强，也不能从里面方便的找到我要的信息
我写的这个宏是把Log文件里每一个步骤的名称、所在Log文件的行号、所花的实际时间和CPU时间提取出来，方便分析
Log文件大致是下面这个样子：
NOTE: Deleting WORK.SS_TEMP (memtype=DATA).
NOTE: PROCEDURE DELETE used (Total process time):
real time 0.00 seconds
cpu time 0.01 seconds
NOTE: The data set WORK.SS_TEMP has 1 observations and 1 variables.
NOTE: DATA statement used (Total process time):
real time 0.00 seconds
cpu time 0.00 seconds
NOTE: There were 1 observations read from the data set WORK.SS_TEMP.
NOTE: The data set WORK.SS_TEMP has 1 observations and 2 variables.
NOTE: DATA statement used (Total process time):
real time 0.00 seconds
cpu time 0.00 seconds
NOTE: PROCEDURE SQL used (Total process time):
real time 0.00 seconds
cpu time 0.00 seconds
可以通过把SAS的Log窗口的内容复制到一个文本文件，或是直接利用下面的代码将Log保存到文本文件中
proc printto log='d:\temp\a.log';
run;
具体的宏如下所示：

1. %macro GetTimeTableForSASLog(InFilePath,TargetTable);
   
2. 
   
3. /**********************************************************************/
   
4. /* 此宏的作用是读取SAS系统生成的Log文件，并将得到的步骤名称和对应的运 */
   
5. /* 行时间保存至结果表格中。其中，InFilePath指定的Log文件，要写全从根 */
   
6. /* 目录至最后的文件名称；TargetTable是结果表格。 */
   
7. /* */
   
8. /* 最终得到的是原始Log文件中包含的步骤名称和对应的运行时间（实际时间 */
   
9. /* 和CPU时间），其中N是步骤在原始Log文件中的行号。 */
   
10. /* */
    
11. /* Created on 2013.12.10 */
    
12. /* Modified on 2013.12.11 */
    
13. /**********************************************************************/
    
14. 
    
15. /* 检查InFilePath的合法性，后缀必须为TXT或LOG */
    
16. %if %SYSFUNC(FIND(&InFilePath,%STR(.))) EQ 0 OR (%SYSFUNC(FIND(&InFilePath,%STR(.))) NE 0 AND %UPCASE(%SCAN(&InFilePath,-1,%STR(.))) NE TXT AND %UPCASE(%SCAN(&InFilePath,-1,%STR(.))) NE LOG) %then %do;
    
17. %put ERROR: The suffix of InFilePath should be txt or log, please check it again.;
    
18. %goto exit;
    
19. %end;
    
20. 
    
21. /* 检查TargetTable的存在性 */
    
22. %if &TargetTable EQ %STR() %then %do;
    
23. %put ERROR: The TargetTable should not be blank, please check it again.;
    
24. %goto exit;
    
25. %end;
    
26. 
    
27. /* 开始进行计算 */
    
28. /* 第一步：导入LOG文件 */
    
29. proc import datafile="&InfilePath" out=&TargetTable replace;
    
30. getnames=no;
    
31. run;
    
32. 
    
33. /* 第二步：处理结果表格 */
    
34. data &TargetTable;
    
35. set &TargetTable;
    
36. N=_N_;
    
37. if SUBSTR(UPCASE(VAR1),1,10) EQ 'NOTE: DATA' OR SUBSTR(UPCASE(VAR1),1,15) EQ 'NOTE: PROCEDURE' OR
    
38. SUBSTR(UPCASE(VAR1),1,9) EQ 'REAL TIME' OR SUBSTR(UPCASE(VAR1),1,8) EQ 'CPU TIME';
    
39. run;
    
40. 
    
41. data &TargetTable;
    
42. set &TargetTable;
    
43. if SUBSTR(UPCASE(VAR1),1,5) EQ 'NOTE:' then do;
    
44. Name=SUBSTR(VAR1,7,FIND(UPCASE(VAR1),'USED')-8);
    
45. end;
    
46. else if SUBSTR(UPCASE(VAR1),1,9) EQ 'REAL TIME' then do;
    
47. Real_Time=SUBSTR(VAR1,PRXMATCH('/\d+.\d+/',VAR1));
    
48. end;
    
49. else if SUBSTR(UPCASE(VAR1),1,9) EQ 'CPU TIME' then do;
    
50. CPU_Time=SUBSTR(VAR1,PRXMATCH('/\d+.\d+/',VAR1));
    
51. end;
    
52. run;
    
53. 
    
54. data &TargetTable(keep=Col_N Col_Name Col_Content);
    
55. set &TargetTable;
    
56. retain Col_N;
    
57. length Col_Name $50;
    
58. length Col_Content $100;
    
59. if Name NE '' then do;
    
60. Col_N=N;
    
61. Col_Name='Name';
    
62. Col_Content=Name;
    
63. output;
    
64. end;
    
65. else if Real_Time NE '' then do;
    
66. Col_Name='Real_Time_Temp';
    
67. Col_Content=Real_Time;
    
68. output;
    
69. end;
    
70. else if CPU_Time NE '' then do;
    
71. Col_Name='CPU_Time_Temp';
    
72. Col_Content=CPU_Time;
    
73. output;
    
74. end;
    
75. run;
    
76. 
    
77. proc transpose data=&TargetTable out=&TargetTable;
    
78. by Col_N;
    
79. id Col_Name;
    
80. var Col_Content;
    
81. run;
    
82. 
    
83. /* 第三步：处理结果表格中的时间变量 */
    
84. data &TargetTable(keep=N Name Real_Time CPU_Time);
    
85. retain N Name Real_Time CPU_Time;
    
86. set &TargetTable(rename=(Col_N=N));
    
87. format Real_Time TIME10.4;
    
88. format CPU_Time TIME10.4;
    
89. if FIND(UPCASE(Real_Time_Temp),'SECONDS') NE 0 then Real_Time=HMS(0,0,SCAN(Real_Time_Temp,1,' '));
    
90. else if LENGTH(COMPRESS(Real_Time_Temp,'.','d')) EQ 2 then Real_Time=HMS(SCAN(Real_Time_Temp,1,':'),SCAN(Real_Time_Temp,2,':'),SCAN(Real_Time_Temp,3,':'));
    
91. else if LENGTH(COMPRESS(Real_Time_Temp,'.','d')) EQ 1 then Real_Time=HMS(0,SCAN(Real_Time_Temp,1,':'),SCAN(Real_Time_Temp,2,':'));
    
92. 
    
93. if FIND(UPCASE(CPU_Time_Temp),'SECONDS') NE 0 then CPU_Time=HMS(0,0,SCAN(CPU_Time_Temp,1,' '));
    
94. else if LENGTH(COMPRESS(CPU_Time_Temp,'.','d')) EQ 2 then CPU_Time=HMS(SCAN(CPU_Time_Temp,1,':'),SCAN(CPU_Time_Temp,2,':'),SCAN(CPU_Time_Temp,3,':'));
    
95. else if LENGTH(COMPRESS(CPU_Time_Temp,'.','d')) EQ 1 then CPU_Time=HMS(0,SCAN(CPU_Time_Temp,1,':'),SCAN(CPU_Time_Temp,2,':'));
    
96. run;
    
97. 
    
98. %exit:
    
99. %mend;

复制代码
另外，我这里的方法属于土法练钢，如果有其他好的办法，欢迎跟贴。

「经管之家」APP：经管人学习、答疑、交友，就上经管之家！
免流量费下载资料----在经管之家app可以下载论坛上的所有资源，并且不额外收取下载高峰期的论坛币。
涵盖所有经管领域的优秀内容----覆盖经济、管理、金融投资、计量统计、数据分析、国贸、财会等专业的学习宝库，各类资料应有尽有。
来自五湖四海的经管达人----已经有上千万的经管人来到这里，你可以找到任何学科方向、有共同话题的朋友。
经管之家（原人大经济论坛），跨越高校的围墙，带你走进经管知识的新世界。
扫描下方二维码下载并注册APP